Protheus :: apconnxcontrol.ocx with Harbour

Harbour também nos permite manipular objetos COM através da função WIN_OLECREATEOBJECT. Um Exemplo bem simples seria:

   1: //--------------------------------------------------------------------

   2: PROCEDURE Main()

   3:  

   4:    LOCAL hUsers    

   5:  

   6:    LOCAL cTEnv  := ""

   7:    LOCAL cTSrv  := ""

   8:    LOCAL cTUser := ""

   9:    LOCAL cTPWD  := ""

  10:    LOCAL nTPort := 0

  11:  

  12:    LOCAL oPtObj

  13:    

  14:    oPtObj := WIN_OLECREATEOBJECT( "apconnxcontrol.apconnx" )

  15:  

  16:    LoadConnectionParams(@cTEnv,@cTSrv,@nTPort,@cTUser,@cTPWD)

  17:    

  18:    oPTObj:Environment     := cTEnv

  19:    oPTObj:Password        := cTPWD

  20:    oPTObj:Port            := nTPort

  21:    oPTObj:Server          := cTSrv

  22:    oPTObj:User            := cTUser

  23:    oPTObj:Connect() 

  24:    

  25:    IF ( oPTObj:Connected )

  26:         oPTObj:AboutBOX()

  27:         ? oPTObj:UsersCount()

  28:         hUsers    := GetUsers(oPTObj)

  29:         SendMessage( oPTObj , hUsers )

  30:         KillPTUsers( oPTObj , hUsers , .T. )

  31:    EndIF

  32:  

  33:    oPTObj:Disconnect()

  34:  

  35:    oPTObj := NIL

  36:  

  37: RETURN

  38:  

  39: //--------------------------------------------------------------------

  40: STATIC FUNCTION GetUsers(oPTObj)

  41:  

  42:     LOCAL aTmp

  43:     LOCAL hTmp

  44:  

  45:     LOCAL cUsers     := oPTObj:GetUsers()

  46:     LOCAL hUsers    := {=>}

  47:     LOCAL aUsers    := hb_aTokens( cUsers , ";"+ Chr(1) )

  48:     LOCAL nUsers    := Len( aUsers )

  49:  

  50:     LOCAL i

  51:     

  52:     FOR i := 1 TO nUsers

  53:         aTmp                        := hb_aTokens( aUsers[ i ] , ";" )

  54:         hUsers[i]                    := {=>}

  55:         hUsers[i]["USER_NAME"]         := aTmp[1]

  56:         hUsers[i]["USER_COMPUTER"]     := aTmp[2]

  57:         hUsers[i]["USER_THREAD_ID"]    := aTmp[3]

  58:         IF ( Len( aTmp ) > 3 )

  59:             hUsers[i]["USER_?"]     := aTmp[4]

  60:         Else

  61:             hUsers[i]["USER_?"]     := ""

  62:         EndIF

  63:     Next i

  64:  

  65:     FOR EACH hTmp IN hUsers

  66:         ? hTmp["USER_NAME"]

  67:         ? hTmp["USER_COMPUTER"]

  68:         ? hTmp["USER_THREAD_ID"]

  69:         ? hTmp["USER_?"]

  70:     NEXT EACH

  71:  

  72: RETURN( hUsers )

  73:  

  74: //--------------------------------------------------------------------

  75: STATIC PROCEDURE LoadConnectionParams(cTEnv,cTSrv,nTPort,cTUser,cTPWD)

  76:     cTEnv  := "NDJ_01"

  77:     cTSrv  := "127.0.0.1"

  78:     nTPort := 4321

  79:     cTUser := "TOTVS"

  80:     cTPWD  := "SIGA"

  81: RETURN

  82:  

  83: //--------------------------------------------------------------------

  84: STATIC PROCEDURE SendMessage( oPTObj , hUsers )

  85:  

  86:     LOCAL hTmp

  87:  

  88:     FOR EACH hTmp IN hUsers

  89:         IF ( Val(hTmp["USER_THREAD_ID"]) > 0 )

  90:             oPTObj:SendMessage(hTmp["USER_NAME"],hTmp["USER_COMPUTER"],hTmp["USER_THREAD_ID"],hTmp["USER_?"],"Message From Harbour")

  91:         EndIF    

  92:     NEXT EACH

  93:  

  94: RETURN

  95:  

  96: //--------------------------------------------------------------------

  97: STATIC PROCEDURE KillPTUsers( oPTObj , hUsers , lWait )

  98:  

  99:     LOCAL hTmp

 100:  

 101:     FOR EACH hTmp IN hUsers

 102:         IF ( Val(hTmp["USER_THREAD_ID"]) > 0 )

 103:             oPTObj:DisconnectUser(hTmp["USER_NAME"],hTmp["USER_COMPUTER"],hTmp["USER_THREAD_ID"],hTmp["USER_?"],lWait)

 104:         EndIF    

 105:     NEXT EACH

 106:  

 107: RETURN

Ao compilar o código Harbour e …

executá-lo,

 

obteremos os seguintes resultados:

Para obter o exemplo siga o link: ..\harbour\samples\ole\apconnxcontrol. hb_apconnx1.prg depende de hbmk.hbm.

Para compilar o código Harbour obtenha o compilador em Harbour Project

[]s
иαldσ dj