BlackTDN :: Função não documentada TCCommit

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️ Olá pessoal, Espero que este post encontre todos vocês bem! É com grande entusiasmo que compartilho que estou expandindo meus serviços como Desenvolvedor AdvPL para novos desafios e colaborações. Com mais de duas décadas de experiência sólida, minha jornada profissional tem sido enriquecedora, com a oportunidade de participar de projetos empolgantes ao longo dos anos. Agora, estou ansioso para trazer minha experiência e habilidades para novas equipes e projetos, trabalhando de forma remota. Minha expertise abrange não apenas AdvPL, mas também outras tecnologias-chave, incluindo JS, SQL, Infraestrutura e Otimização de Processos. Acredito que essa combinação de conhecimentos me permite oferecer soluções abrangentes e eficazes para uma variedade de necessidades de desenvolvimento. Acredito que a tecnologia tem o poder de transformar negócios e impulsionar o sucesso, e estou comprometido em ajudar meus clientes a alcançar seu

BlackTDN :: Função não documentada TCCommit

TCCommit é uma função não documentada no TDN (não para nós, meros mortais). Ela é uma função de uso Exclusivo com o dbAcces (TOPCONN) e possui as seguintes características.

Função:TCCommit( nOpc , uParam )

nOPC : Obrigatório	Tipo Numérico, define as opções para TCCommit
uParam : Opcional	Tipo Indefinido.

nOPC

1	Begin Transaction
2	Commit
3	RollBack
4	End Transaction
5	uParam==.T. (prepara a Criação de Tabela no AS/400) uparam==.F.(finaliza a Criação de Tabela no AS/400)

Um exemplo de uso para a TCCommit é o programa U_R3V2Sal.prg (usado pelo meu “Brother” Rodrigo “OverFail” para retornar o salário do funcionário a partir do SR3 e de acordo com a Data de Referência. Rodrigo teve que recalcular a Folha de Pagamento de uma Empresa do ano de 2011) .

#INCLUDE "PROTHEUS.CH"
#INCLUDE "TRYEXCEPTION.CH"
/*
    Funcao:     R3V2Sal
    Autor:      Marinaldo de Jesus
    Data:       02/03/2012
    Descricao: Atualizar Salario do SRA de acordo com o R3_VALOR e Data de Referencia
*/
User Function R3V2Sal( cFil , cMat , cSData )

Local aArea := GetArea()
Local aSRAArea := SRA->( GetArea() )

    Local cCRLF          := CRLF
    Local cQuery         := ""
    Local cMsgOut        := ""
    Local cKeySeek       := ""

    Local cSRASqlName    := RetSqlName("SRA")
    Local cSR3SqlName    := RetSqlName("SR3")
    Local cTCSqlError

    Local nSalario       := 0
    Local nRecno         := 0
    Local nSRAOrder      := RetOrder( "SRA" , "RA_FILIAL+RA_MAT" )

    DEFAULT cFil         := SRA->RA_FILIAL
    DEFAULT cMat         := SRA->RA_MAT
    DEFAULT cSData       := Dtos( dDataBase )

cKeySeek += ( cFil + cMat )

    cQuery    += "UPDATE" + cCRLF
    cQuery    += "    " + cSRASqlName + cCRLF
    cQuery    += "SET" + cCRLF
    cQuery    += "    " + cSRASqlName+".RA_SALARIO = " + cSR3SqlName+".R3_VALOR" + cCRLF
    cQuery    += "FROM" + cCRLF
    cQuery    += "    (" + cCRLF
    cQuery    += "        SELECT" + cCRLF
    cQuery    += "            SRA.RA_FILIAL," + cCRLF
    cQuery    += "            SRA.RA_MAT," + cCRLF
    cQuery    += "            MAX(SR3.R3_DATA) R3_DATA" + cCRLF
    cQuery    += "        FROM" + cCRLF
    cQuery    += "            " + cSRASqlName + " AS SRA," + cCRLF
    cQuery    += "            " + cSR3SqlName + " AS SR3" + cCRLF
    cQuery    += "        WHERE" + cCRLF
    cQuery    += "            SRA.D_E_L_E_T_ = ' '" + cCRLF
    cQuery    += "        AND" + cCRLF
    cQuery    += "            SR3.D_E_L_E_T_ = ' '" + cCRLF
    cQuery    += "        AND" + cCRLF
    cQuery    += "            SRA.RA_FILIAL = SR3.R3_FILIAL" + cCRLF
    cQuery    += "        AND" + cCRLF
    cQuery    += "            SRA.RA_MAT = SR3.R3_MAT" + cCRLF
    cQuery    += "        AND" + cCRLF
    cQuery    += "            SR3.R3_DATA <= '" + cSData + "'" + cCRLF
    cQuery    += "        GROUP BY" + cCRLF
    cQuery    += "            SRA.RA_FILIAL," + cCRLF
    cQuery    += "            SRA.RA_MAT" + cCRLF
    cQuery    += "    ) AS SAL," + cCRLF
    cQuery    += "    " + cSR3SqlName+ " AS " +cSR3SqlName + cCRLF
    cQuery    += "WHERE" + cCRLF
    cQuery    += "    " +cSRASqlName+".RA_FILIAL = '" + cFil + "'" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " +cSRASqlName+".RA_MAT = '" + cMat + "'" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    SAL.RA_FILIAL = "+cSRASqlName+".RA_FILIAL" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    SAL.RA_MAT    = "+cSRASqlName+".RA_MAT" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSRASqlName+".D_E_L_E_T_ = ' '" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSR3SqlName+".D_E_L_E_T_ = ' '" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSRASqlName+".RA_FILIAL = " + cSR3SqlName+".R3_FILIAL" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSRASqlName+".RA_MAT = " + cSR3SqlName+".R3_MAT" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSR3SqlName+".R3_DATA = SAL.R3_DATA" + cCRLF
    cQuery    += "AND" + cCRLF
    cQuery    += "    " + cSR3SqlName+".R3_VALOR > 0" + cCRLF

TRYEXCEPTION

TcCommit(1,ProcName()) //Begin Transaction

        IF ( TcSqlExec( cQuery ) < 0 )
            cTCSqlError := TCSQLError()
            ConOut( cMsgOut += ( "[ProcName: " + ProcName() + "]" ) )
            cMsgOut += cCRLF
            ConOut( cMsgOut += ( "[ProcLine:" + Str(ProcLine()) + "]" ) )
            cMsgOut += cCRLF
            ConOut( cMsgOut += ( "[TcSqlError:" + cTCSqlError + "]" ) )
            cMsgOut += cCRLF
            UserException( cMsgOut )
        EndIF

        TcCommit(2,ProcName())    //Commit
        TcCommit(4)                //End Transaction
        SRA->( dbSetOrder( nSRAOrder ) )
        nRecno := SRA->( Recno() )
        SRA->( dbGoTop() )        //Forco o Refresh no TOP
        SRA->( dbGoTo( nRecno ) )
        IF SRA->( MsSeek( cKeySeek , .F. ) )
            nSalario := SRA->RA_SALARIO
        Else
            SRA->( dbGoTo( nRecno ) )
        EndIF

CATCHEXCEPTION

TcCommit(3) //RollBack
TcCommit(4) //End Transaction

ENDEXCEPTION

RestArea( aSRAArea )
RestArea( aArea )

Return( nSalario )

outro exemplo:

#ifdef TOP
    If ( TCSrvType() == 'AS/400' ) .And. ( cDriver == 'TOPCONN' )
        TCCommit(5,.T.)
        DbCreate(cArquivo,aStru,cDriver)
        TCCommit(5,.F.)
        cCommand := "CHGOBJOWN OBJ("+AllTrim(cArquivo)+") OBJTYPE(*FILE) NEWOWN(QUSER)"
        TCSysExe(cCommand)
    Else
        DBCreate(cArquivo,aStru,cDriver)
    EndIf
#else
    DBCreate(cArquivo,aStru,cDriver)
#endif

[]s

иαldσ dj

BlackTDN :: RLeg ~ Desvendando a Função ParamBox

Para quem precisar desenvolver uma interface de entrada de dados, coisa rápida, e não quer ter aquele trabalhão danado que todos já sabemos, o Protheus tem uma função que ajuda muito, é uma interface semelhante a função Pergunte, porém com muito mais opção de objeto de entrada de dados, alias até colocar o scrollbox desta interface com todos os objetos em outra MsDialog ou Wizard é simples. Vejam o exemplo abaixo, boa sorte! Rleg. //---------------------------------------------------------- // Função exemplo utilizando a função ParamBox() //---------------------------------------------------------- User Function xParamBox() Local aRet := {} Local aParamBox := {} Local aCombo := {"Janeiro","Fevereiro","Março","Abril","Maio","Junho","Julho","Agosto","Setembro","Outubro","Novembro","Dezembro"} Local i := 0 Private cCadastro := "xParambox" // ---------------

Protheus :: Chamando Funções do Menu Diretamente e sem a Necessidade de Login

Ferne$ perguntou: "...é possível abrir alguma rotina do sistema sem solicitar login ao usuário, como por exemplo a rotina MATA010..." Sim Ferne$, é possível sim. Abaixo um Exemplo para a Chamada à função MATA010 sem a necessidade de Login no sistema. #INCLUDE "PROTHEUS.CH" #INCLUDE "TBICONN.CH" /*/ Funcao: MATA010Ex Data: 30/04/2011 Autor: Marinaldo de Jesus Descricao: Executar a Funcao MATA010 diretamente sem a necessidade de LOGIN no Protheus Sintaxe: 1 ) U_MATA010Ex ( Chamada diretamente na Tela de Entrada do Sistema ) ; ou 2 ) totvsclient.exe -q -p=u_MATA010Ex -a=01;01 -c=rnp_local -e=rnp -m -l ( Chamada Via Linha de Comando ) /*/ User Function MATA010Ex( cEmpFil ) Local aEmpFil Local bWindowInit := { || __Execute( "MATA010()" , "xxxxxxxxxxxxxxxxxxxx" , "MATA010" , "SIGAFAT" , "SIGAFAT", 1 , .T. ) } Local cEmp Local cFil Local cMod Local cModName := "SIGAFAT" DEFA

BlackTDN :: Customizando a interface de Login no Protheus e by You

A publicação “ BlackTDN :: By You e sua nova tela de login ” de nosso amigo OBona deu o que falar e, em função disso, esse que a muito não vos escreve resolveu criar uma versão onde será possível personalizar, “por completo”, a tela de login no Protheus/by You. Considerando que OBona já havia “mapeado, identificado e customizado” as imagens peguei-as emprestadas para o exemplo que se segue: O primeiro passo para a customização “total” da interface de login do Protheus/by You será implementar o “Ponto de Entrada” ChgPrDir (Diretório de impressão) . Usaremos esse PE juntamente como programa U_FindMsObject.prg (apresentado pela primeira vez em: Protheus :: ADVPL : The Container : Presents Pandora's box ). Diferente do exemplo proposto por OBona, que substitui, durante o processo de compilação, as imagens padrões do sistema (excluindo-as) por imagens customizadas (com o mesmo nome) este novo exemplo mantém, no RPO, as imagens padrões adicionando novas imagens customizadas que serã

Comentários

Rodrigo "OverFail"3 de março de 2012 às 05:15
A função ficou show no Roteiro de Calculo!!!! Rodrigo OverFail feat Naldo Dj ON x TOTVS-ABM Off... hehehehe!!!!
ResponderExcluir
Respostas
иαldσ dj29 de maio de 2012 às 22:45
Corrigi os valores dos parâmetros:

Função:TCCommit( nOpc , uParam )

nOPC : Obrigatório Tipo Numérico, define as opções para TCCommit
uParam : Opcional Tipo Indefinido.

Onde nOPC

1 Begin Transaction
2 End Transaction
3 RollBack
4 Commit
5 Especifico para AS/400?
ResponderExcluir
Respostas

Adicionar comentário

BlackTDN

Pesquisar este blog

Postagem em destaque

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️