BlackTDN Search

sexta-feira, 6 de maio de 2011

Protheus :: Convertendo arquivos PDF em JPEG usando WaitRunSrv

Gilberto Rafael de Souza: Analista da franquia da TOTVS de SC escreveu:

"Já abri chamado com o suporte, fiz alguns pesquisas, e por fim postei uma necessidade no forum do Help Fácil... olha se já tratasse algo assim:

Temos uma customização que efetua a impressão gráfica usando o componente TMSPrinter.

Precisamos imprimir no verso dessa impressão uma imagem que esta gravada no servidor em formato PDF.

Existe alguma forma de "ler" este arquivo e imprimir no Protheus?

Já pensei em converter dinamicamente o arquivo PDF para JPG, mas não encontrei nenhum programa que faça isso em batch (via linha de comando e em tempo de execução do relatório)."

A solução:

Giba (se é que posso te chamar assim hehe). Para a solução do seu problema vamos usar a WaitRunSrv() em Conjunto com duas aplicações externas:

 ImageMagick e  GhostScript

Baixe e instale, de acordo com o sistema operacional do seu SO a versão do ImageMagick e do GhostScript. Este é último é necessário para que o ImageMagick possa converter o PDF para outros formatos, inclusive JPEG.

ImageMagick baixei a partir de: http://www.imagemagick.org/download/binaries/ImageMagick-6.6.9-8-Q16-windows-dll.exe e;

O "download" do GhostScrit fiz em http://downloads.ghostscript.com/public/


Um pequeno código para testar a conversão.

#INCLUDE "PROTHEUS.CH"
/*/
 Programa: U_PDFtoJPG()
 Autor:  Marinaldo de Jesus
 Data:  06/05/2011
 Uso:  Converter Arquivos PDF em JPEG Usando WaitRunSrv(), ImageMagick e GhostScript
/*/
User Function PDFtoJPG()

 Local cImgMagickPath  := GetSrvProfString( "ImageMagickHome" , "c:\Arquivos de programas\ImageMagick-6.6.9-Q16\" )
 Local cPDFFileToJPG  := "D:\U_PDFToJPG\logo.pdf"
 Local cJPGFileName  := ""
 Local cWaitRunExec  := ""
 
 BEGIN SEQUENCE

  IF !File( cPDFFileToJPG , 1 ) //FullPath Use File( cJPGFileName ) se desejar verificar a Partir do RootPath do Protheus
   BREAK
  EndIF
 
  cJPGFileName := "D:\U_PDFToJPG\"+( CriaTrab( NIL , .F. ) + ".jpg" )
  While File( cJPGFileName , 1 ) //FullPath Use File( cJPGFileName ) se desejar verificar a Partir do RootPath do Protheus
   cJPGFileName := "D:\U_PDFToJPG\"+( CriaTrab( NIL , .F. ) + ".jpg" )
  End While
 
  cImgMagickPath := AllTrim( cImgMagickPath )
  IF !( SubStr( cImgMagickPath , -1 ) == "\" )
   cImgMagickPath += "\"
  EndIF

  /*/
   A T E N C A O ! ! !
   Observar que o windows, em sua linha de comando, e sensivel a espacos na arvore de diretorios para execucao...
  /*/
  cWaitRunExec := cImgMagickPath + "convert.exe"
  IF ( " " $ cWaitRunExec )
   cWaitRunExec  := '"' + cWaitRunExec   + '"'
  EndIF
  
  IF !( WaitRunSrv( cWaitRunExec + " " + cPDFFileToJPG + " " + cJPGFileName , .T. , cImgMagickPath ) )
   cJPGFileName := ""
   BREAK
  EndIF

  IF !File( cJPGFileName )
   cJPGFileName := ""   
  EndIF

 END SEQUENCE 

Return( cJPGFileName )


Obs.: Para cada página do arquivo PDF será gerada uma imagem em JPG.

Mais uma vez, para baixar o programa de exemplo, clique aqui.

[]s
иαldσ dj

8 comentários:

  1. aff, ow muda de linguagem.
    vc consegue fazer tudo no advpl!

    ParaÔÔ

    ResponderExcluir
  2. Eu tenho que admitir.
    Tenho inveja de você!

    Mas é uma inveja boa, nao se preocupe!
    Good job man, u're the best of bests.

    Faça um post, com um combo de funções criadas por você nos fontes de RH. Use este filtro (RH*.PR?).

    ResponderExcluir
  3. Vitor Emanuel Batista10 de maio de 2011 08:33

    Teria como desenvolver em ADVPL uma função que tratasse imagens (principalmente .PNG) em um diretório (ex: c:\temp\imagem.png), redimensionando e rotacionando, salvando novamente em um diretório (ex: c:\temp\imagem2.png)

    Belo trabalho!

    ResponderExcluir
  4. Vitor,

    Advpl não serve a esse propósito, mas podemos usa-la, em conjunto com ImageMagick, para esse fim.

    Você poderá manipular a imagem da maneira que desejar, alterando as suas propriedades, qualidade, dentre outras coisas.

    []s
    иαldσ dj

    ResponderExcluir
  5. Vitor Emanuel Batista12 de maio de 2011 08:29

    O ideal é não ter software de terceiros.
    No máximo uma dll que poderia estar fazendo este processo por fora (em tempo de execução sem o conhecimento do usuário).

    Abraço

    ResponderExcluir
  6. Vitor,

    Sugeri ImageMagick por ser uma solução completa, portável e gratuita. Mas nada impede que desenvolva a sua própria aplicação.

    []s
    иαldσ dj

    ResponderExcluir
  7. Gilberto Rafael de Souza2 de junho de 2011 11:58

    Naldo, funcionou perfeitamente a solução...

    Obrigado pela Ajuda!

    Parabéns.

    ResponderExcluir
  8. Pessoal eu leigo em ADVPL, e estou precisando URGENTEMENTE dessa solução de vcs... Alguém pode me ajudar??? obrigado

    ResponderExcluir