Protheus :: Tratamento de Erro :: Simulando Try/Catch

Sabemos que para tratamento de erros/exceções em Advpl devemos trabalhar com as funções ErrorBlock() e/ou SysErrorBlock() e BEGIN SEGUENCE/RECOVER/END como no exemplo abaixo:

Function TrySample1()

//Salvando o bloco de erro do sistema e Atribuindo tratamento personalizado Local bError := ErrorBlock( { |oError| MyError( oError ) } )

BEGIN SEQUENCE

 //Forçando um erro para avalia-lo.
 __EXCEPTION__->ERROR := "__EXCEPTION__"
RECOVER
 //"Se ocorreu erro, após o BREAK, venho para cá"
 MsgInfo( "Peguei o Desvio do BREAK" )
END SEQUENCE

MsgInfo( "Continuo após o tratamento de erro" )

//Restaurando bloco de erro do sistema
ErrorBlock( bError )

Return( NIL )

Static Function MyError( oError )
MsgInfo( oError:Description , "Deu Erro" )
BREAK
Return( NIL )

Para Simular o mesmo tratamento acima, usando agora try/catch, que no nosso exemplo estará como TRYEXCEPTION, CATCHEXCEPTION e ENDEXCEPTION, proceda da seguinte forma:

Baixe o arquivo tryexception.ch clicando aqui. Inclua-o no cabeçalho do seu programa utilizando a seguine sintaxe: #include "tryexception.ch"

e, repetindo o exemplo anterior, teremos:

#include "tryexception.ch"

Static Function TrySample2()

Local bError := { |oError| MyError( oError ) }
Local oError

TRYEXCEPTION USING bError
 //Forçando um erro para avalia-lo.
 __EXCEPTION__->ERROR := "__EXCEPTION__"
CATCHEXCEPTION USING oError
 //"Se ocorreu erro, após o BREAK, venho para cá"
 MsgInfo( oError:Description , "Peguei o Desvio do BREAK" )
ENDEXCEPTION

MsgInfo( "Continuo após o tratamento de erro" )

Return( NIL )

Function TrySample3()

Local aParamX := {"Serei Alterado",2,3,4}
Local bError := { |oError,aParam| Error( oError , @aParam ) }
Local oMyError

TRY EXCEPTION USING bError PARAMETERS aParamX
 __EXCEPTION__->EXCEPTION := "__EXCEPTION__"
CATCH EXCEPTION USING oMyError
 MsgInfo( aParamX[1] , "Changed in Error" )
 MsgInfo( oMyError:Description )
END EXCEPTION

Return( NIL )

Function TrySample4()

Local cAliasTmp := GetNextAlias()
Local cLike := "APT%"
Local oError
Local oException

BEGINSQL ALIAS cAliasTmp
 SELECT
   MAX(RC1.RC1_NUMTIT) RC1_NUMTIT
 FROM
   %table:RC1% RC1
 WHERE
   RC1.RC1_FILIAL = %exp:xFilial("RC1")% AND
   RC1.RC1_NUMTIT LIKE %exp:cLike% AND
   RC1.%NotDel%
ENDSQL

TRY EXCEPTION
 IF ( cAliasTmp )->( Eof() .or. Empty( RC1_NUMTIT ) )
   UserException("No Data")
   TRYEXCEPTION
     MsgInfo( ( cAliasTmp )->RC1_NUMTIT )
     UserException("Data Found")
   CATCHEXCEPTION
     MsgInfo( oException:Description )
   ENDEXCEPTION
 EndIF
CATCH EXCEPTION USING oError
 MsgInfo( oError:Description )
END TRY

Return( NIL )

Function Error( oError , aParameters )

IF !Empty( aParameters ) .and. ( Len( aParameters ) > 1 )
 MsgInfo( AllToChar( aParameters[1] ) , "Call Stack: " + ProcName() ) aParameters[1] := "ProcName: " + ProcName() + " :: ProcLine: " + AllTrim( AllToChar( ProcLine() -1 ) ) + " ::Alterou o Conteúdo desse elemento do Array"
EndIF

Break

Return( NIL )

Se desejar baixar o arquivo de exemplo u_tsttrycatch.prg, clique aqui.

Para baixar todos os arquivos de exemplo usados neste "post" clique aqui.

[]s иαldσ dj