Li recentemente, em um documento oficial sobre a liguagem ADVPL que:
"Static Function
Funções ADVPL tradicionais, cuja visibilidade está restrita as funções descritas no mesmo arquivo de código fonte no qual estão definidas."
Será que isso é mito ou verdade.
Parafraseando Eisnten, "depende do ponto de vista de quem vê". É sabido por muitos, inclusive por aqueles que escrevem o manual de ADVPL da Totvs/Microsiga, que as "Static Function" estão restritas apenas ao arquivo fonte que as declarou. De uma certa forma isso é verdade. Mas, lembro-me de que quanto ainda trabalhava no desenvolvimento da "Microsiga", hoje IP, que isso sempre me intrigava. Será que existiria uma maneira de tornar uma "Static Function" visível "Globalmente" ou seja, será que eu poderia chamar uma "Static Function" declarada em um programa "x" no programa "y".
Depois de muito quebrar a cabeça, e pensando no funcionamento de um bloco de código, que ele extende a visibilidade de uma variável até a sua duração. Tive a seguinte idéia:
Já que uma "Static Function" só pode ser usada dentro do programa fonte que a declarou, se eu criar uma "Function ou User Function" (funções de escopo "global") que de uma certa forma as "exporte", tornando-as "visíveis" fora do seu limite, será que seriam executadas. Para minha surpresa essa premissa era e é verdadeira.
Para validar essa premissa escrevi a seguinte função: BldcExecInFun()
1Function BldcExecInFun( cExecIn , aFormParam )
2
3Local nAt
4Local nParam
5Local nParams
6
7DEFAULT cExecIn := ""
8
9IF !Empty( cExecIn )
10DEFAULT aFormParam := {}
11 _SetOwnerPrvt( "__aFormais__" , aFormParam )
12 cExecIn := StrTran( cExecIn , " " , "" )
13 nParams := Len( __aFormais__ )
14 IF ( ( nAt := At( "(" , cExecIn ) ) > 0 )
5 cExecIn := SubStr( cExecIn , 1 , nAt )
16 Else
17 cExecIn += "("
18 EndIF
19 IF ( nParams > 0 )
20 For nParam := 1 To nParams
21 cExecIn += "@__aFormais__["+AllTrim(Str(nParam))+"],"
22 Next nParam
23 cExecIn := SubStr( cExecIn , 1 , Len( cExecIn ) - 1 ) + ")"
24 Else
25 cExecIn += ")"
26 EndIF
27EndIF
28
29Return( cExecIn )
|
Bem, e pra que serve a BldcExecInFun()? Isoladamente não serve para nada. Mas se usada dentro dos programas que possuem "Static Function" ela permitirá que as "Static Function" ali declaradas, bem como as variáveis de escopo "Static" sejam exportadas e usadas em qualquer ponto do sistema.
Nos programas que disponibilizei para "download" no "post":
Protheus :: WebService Nota Fiscal de Saida Tools (Versão Final) , tem um exemplo de uso. Por exemplo, o programa "u_wsUtils.prx", possui funções que deverão ser usadas pelos demais programas, considerando que é um programa customizado, para que as funções ali existentes pudessem ser usadas em outros programas eu deveria declará-las como "User Function". Mas não fiz isso. Existe apenas uma "User Function" as demais são todas "Static Function" e a única "User Function" não faz nada mais do que disponibilizar as "Static Function" para uso em outros programas do sistema. Ela faz uso da BldcExecInFun() para tornar as "Static Function" ali declaradas, apesar de restritas ao programa, de usabilidade "global" Ou seja, podem ser executadas em qualquer ponto do sistema.
A declaração da única função de "escopo global" foi feita da seguinte forma:
1: /*/
2: Função: u_WsUtilsExec
3: Autor: Marinaldo de Jesus
4: Data: 01/09/2010
5: Descrição: Executar Funcoes Dentro WsUtilsExec
6: Sintaxe: u_WsUtilsExec( cExecIn , aFormParam )
7: Parametros: <Vide Parametros Formais>
8: Retorno: uRet
9: Uso: Disponibilizar as Static Functions desse prg para uso Geral
10: /*/
11: User Function WsUtilsExec( cExecIn , aFormParam )
12:
13: Local uRet
14:
15: DEFAULT cExecIn := ""
16: DEFAULT aFormParam := {}
17:
18: IF !Empty( cExecIn )
19: cExecIn := BldcExecInFun( cExecIn , @aFormParam )
20: uRet := &( cExecIn )
21: EndIF
22:
23: Return( uRet )
|
Ela é tão simples que existe mais documentação do que código.
Permitindo que as "Static Function" fossem usadas no programa "u_wsNFSService.prx" da seguinte forma:
//Retirando a mascara do CNPJ
Self:CNPJ := u_WsUtilsExec( "UnMaskCNPJ" , { Self:CNPJ } )
//Obtendo um ID Valido
aParameters := { cGetIdEntErr }
cIdEnt := u_WsUtilsExec( "GetIdEnt" , @aParameters )
cGetIdEntErr := aParameters[1]
//Obtendo um ID Valido
aParameters := { cGetIdEntErr }
cIdEnt := u_WsUtilsExec( "GetIdEnt" , @aParameters )
cGetIdEntErr := aParameters[1]
//Calculando a Paginação para apresantação do Resultado do WebService
aParamiters := { nPagLim , nToReg , Self:nPagsDe , nPagIni , nPagFim }
nTotPags := U_WsUtilsExec( "CalcNumPag" , @aParamiters )
nPagIni := aParamiters[4]
nPagFim := aParamiters[5]
|
Observe que o "array" que serve de "parâmetro de Entrada" também torna-se, por referência, "Um parâmetro de Saída".
Bem, o Mito foi quebrado.
"Tô Certo!"
[]s
иαldσ dj
...
Poderia ser mencionado também a função StaticCall, sendo utilizado como exemplo abaixo:
ResponderExcluiraRotina := StaticCall(MNTA010,MENUDEF)
Grande Vitor!!!
ResponderExcluirTentei achar essa "tal" de StaticCall mas não consegui. Pelo menos no binário e RPO que estou utilizando não consegui encontrar. Não é Função Advpl pois não a achei com FindFunction("StaticCall"), não é função da API (pois não achei na pilha retornada pela __FunArr()), enfim, não existe (rs). Mas pelo que pude perceber ela exporta as opções do aRotina.
Mas enfim,
Valeu pela contribuição.
"Tô Certo!"
[]s
иαldσ dj