Pular para o conteúdo principal

Postagem em destaque

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️ Olá pessoal, Espero que este post encontre todos vocês bem! É com grande entusiasmo que compartilho que estou expandindo meus serviços como Desenvolvedor AdvPL para novos desafios e colaborações. Com mais de duas décadas de experiência sólida, minha jornada profissional tem sido enriquecedora, com a oportunidade de participar de projetos empolgantes ao longo dos anos. Agora, estou ansioso para trazer minha experiência e habilidades para novas equipes e projetos, trabalhando de forma remota. Minha expertise abrange não apenas AdvPL, mas também outras tecnologias-chave, incluindo JS, SQL, Infraestrutura e Otimização de Processos. Acredito que essa combinação de conhecimentos me permite oferecer soluções abrangentes e eficazes para uma variedade de necessidades de desenvolvimento. Acredito que a tecnologia tem o poder de transformar negócios e impulsionar o sucesso, e estou comprometido em ajudar meus clientes a alcançar seu

Protheus :: WebServices : Exemplo de uso da Estrutura TableView

Um pequeno e simples exemplo de como utilizar a Estrutura TableView nos WebServices em ADVPL. Os componentes de TableView são: TableStruct e TableData.

Carregamos em TableView:TableStruct as informações da Estrutura de uma Tabela de acordo com o Array retornado pela função dbStruct().

Já TableView:TableData deverá conter os itens da Tabela de Acordo com a estrutura definida em TableStruct.

Para maior compreensão, eis o exemplo:


#INCLUDE "APWEBSRV.CH"
#INCLUDE "PROTHEUS.CH"
#INCLUDE "DBSTRUCT.CH"
#INCLUDE "TRYEXCEPTION.CH"
/*/
 WebService: U_TblViewSample
 Autor:   Marinaldo de Jesus
 Data:   25/06/2011
 Descricao: Exemplo de Uso da Estrutura de WS TableView
 Uso:   WebServices
/*/
WSSERVICE U_TblViewSample DESCRIPTION "Exemplode Uso da Estrutura TableView" NAMESPACE "http://u_tblviewsample.apw"

 WSDATA Table AS TableView
 WSDATA Alias AS STRING
 WSDATA rInit AS INTEGER
 WSDATA rEnd  AS INTEGER

 WSMETHOD GET  DESCRIPTION "Exemplo de Uso da TableView: Get"

ENDWSSERVICE

/*/
 WsMethod: GET
 Autor:   Marinaldo de Jesus
 Data:   25/06/2011
 Descricao: Obtendo informacoes de uma tabela usando TableView
 Uso:   WebServices
/*/
WSMETHOD GET WSRECEIVE Alias , rInit , rEnd WSSEND Table WSSERVICE U_TblViewSample

 Local adbStruct
 
 Local cValue
 Local cDBSType
 
 Local lWsMethodRet  := .T.

 Local nItem
 Local nRecno
 Local nField
 Local nFields

 Local oException
 
 Local uValue

 TRYEXCEPTION
 
  Self:Alias  := Upper( Self:Alias )
  DEFAULT Alias := Self:Alias

  IF !ChkFile( Self:Alias )
   ExUserException( "Problema na abertura da Tabela: " + Self:Alias )
  EndIF

  Self:Table    := WsClassNew( "TableView" ) 
  Self:Table:TableStruct := {}

  adbStruct    := ( Self:Alias )->( dbStruct() )
  nFields     := Len( adbStruct )

  For nField := 1 To nFields
   aAdd( Self:Table:TableStruct , WsClassNew( "FieldStruct" ) )
   Self:Table:TableStruct[ nField ]:FldName := adbStruct[ nField ][ DBS_NAME ]
   Self:Table:TableStruct[ nField ]:FldType := adbStruct[ nField ][ DBS_TYPE ]
   Self:Table:TableStruct[ nField ]:FldSize := adbStruct[ nField ][ DBS_LEN  ]
   Self:Table:TableStruct[ nField ]:FldDec  := adbStruct[ nField ][ DBS_DEC  ]
  Next nField 

  Self:Table:TableData := {}
  
  nItem := 0

  For nRecno := Self:rInit To Self:rEnd
   ( Self:Alias )->( dbGoto( nRecno ) )
   IF ( Self:Alias )->( Eof() .or. Bof() )
    Loop
   EndIF
   aAdd( Self:Table:TableData , WsClassNew( "FieldView" ) )
   ++nItem
   Self:Table:TableData[ nItem ]:FldTag := Array( nFields )
   For nField := 1 To nFields
    cDBSType := adbStruct[ nField ][ DBS_TYPE ]
    uValue  := ( Self:Alias )->( FieldGet( nField ) )
    Do Case
    Case ( cDBSType == "N" )
     cValue := Str( uValue , adbStruct[ nField ][ DBS_LEN ] , adbStruct[ nField , DBS_DEC ] )
    Case ( cDBSType == "D" )
     cValue := Dtos( uValue )
    Case ( cDBSType == "L" )
     cValue := IF( uValue , ".T." , ".F." )
    OtherWise
     cValue := uValue
    EndCase
    Self:Table:TableData[ nItem ]:FldTag[ nField ] := AllTrim( cValue )
   Next nField
  Next nLoop

  IF ( nItem == 0 )
   ExUserException( "Não Existem Registros a Serem Apresentados para a Tabela: " + Self:Alias )
  EndIF

 CATCHEXCEPTION USING oException

  lWsMethodRet := .F.

  SetSoapFault( ProcName() , oException:Description )

 ENDEXCEPTION

Return( lWsMethodRet ) 
Obtenha-o, clicando aqui


[]s
иαldσ dj

Comentários

Postagens mais visitadas deste blog

BlackTDN :: RLeg ~ Desvendando a Função ParamBox

Para quem precisar desenvolver uma interface de entrada de dados, coisa rápida, e não quer ter aquele trabalhão danado que todos já sabemos, o Protheus tem uma função que ajuda muito, é uma interface semelhante a função Pergunte, porém com muito mais opção de objeto de entrada de dados, alias até colocar o scrollbox desta interface com todos os objetos em outra MsDialog ou Wizard é simples. Vejam o exemplo abaixo, boa sorte! Rleg. //---------------------------------------------------------- // Função exemplo utilizando a função ParamBox() //---------------------------------------------------------- User Function xParamBox() Local aRet := {} Local aParamBox := {} Local aCombo := {"Janeiro","Fevereiro","Março","Abril","Maio","Junho","Julho","Agosto","Setembro","Outubro","Novembro","Dezembro"} Local i := 0 Private cCadastro := "xParambox" // ---------------

BlackTDN :: Customizando a interface de Login no Protheus e by You

A publicação “ BlackTDN :: By You e sua nova tela de login ”  de nosso amigo OBona deu o que falar e, em função disso, esse que a muito não vos escreve resolveu criar uma versão onde será possível personalizar, “por completo”, a tela de login no Protheus/by You. Considerando que OBona já havia “mapeado, identificado e customizado” as imagens peguei-as emprestadas para o exemplo que se segue: O primeiro passo para a customização “total” da interface de login do Protheus/by You será implementar o “Ponto de Entrada” ChgPrDir (Diretório de impressão) . Usaremos esse PE juntamente como programa U_FindMsObject.prg (apresentado pela primeira vez em: Protheus :: ADVPL : The Container : Presents Pandora's box ). Diferente do exemplo proposto por OBona, que substitui, durante o processo de compilação, as imagens padrões do sistema (excluindo-as) por imagens customizadas (com o mesmo nome) este novo exemplo mantém, no RPO, as imagens padrões adicionando novas imagens customizadas que serã

Protheus :: Chamando Funções do Menu Diretamente e sem a Necessidade de Login

Ferne$ perguntou: "...é possível abrir alguma rotina do sistema sem solicitar login ao usuário, como por exemplo a rotina MATA010..." Sim Ferne$, é possível sim. Abaixo um Exemplo para a Chamada à função MATA010 sem a necessidade de Login no sistema. #INCLUDE "PROTHEUS.CH" #INCLUDE "TBICONN.CH" /*/ Funcao: MATA010Ex Data: 30/04/2011 Autor: Marinaldo de Jesus Descricao: Executar a Funcao MATA010 diretamente sem a necessidade de LOGIN no Protheus Sintaxe: 1 ) U_MATA010Ex ( Chamada diretamente na Tela de Entrada do Sistema ) ; ou 2 ) totvsclient.exe -q -p=u_MATA010Ex -a=01;01 -c=rnp_local -e=rnp -m -l ( Chamada Via Linha de Comando ) /*/ User Function MATA010Ex( cEmpFil ) Local aEmpFil Local bWindowInit := { || __Execute( "MATA010()" , "xxxxxxxxxxxxxxxxxxxx" , "MATA010" , "SIGAFAT" , "SIGAFAT", 1 , .T. ) } Local cEmp Local cFil Local cMod Local cModName := "SIGAFAT" DEFA