Pular para o conteúdo principal

Postagem em destaque

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️

🚀 Oferecendo Serviços Remotos de Desenvolvedor AdvPL e Mais 🖥️ Olá pessoal, Espero que este post encontre todos vocês bem! É com grande entusiasmo que compartilho que estou expandindo meus serviços como Desenvolvedor AdvPL para novos desafios e colaborações. Com mais de duas décadas de experiência sólida, minha jornada profissional tem sido enriquecedora, com a oportunidade de participar de projetos empolgantes ao longo dos anos. Agora, estou ansioso para trazer minha experiência e habilidades para novas equipes e projetos, trabalhando de forma remota. Minha expertise abrange não apenas AdvPL, mas também outras tecnologias-chave, incluindo JS, SQL, Infraestrutura e Otimização de Processos. Acredito que essa combinação de conhecimentos me permite oferecer soluções abrangentes e eficazes para uma variedade de necessidades de desenvolvimento. Acredito que a tecnologia tem o poder de transformar negócios e impulsionar o sucesso, e estou comprometido em ajudar meus clientes a alcançar seu

BlackTDN :: GDToExcel ~ Usando FWMsExcel para exportar informações da GetDados

 

/*/
Funcao: GDToExcel
Autor: Marinaldo de Jesus
Data: 01/06/2013
Descricao: Mostrar os Dados no Excel
Sintaxe: StaticCall(NDJLIB001,GDToExcel,aHeader,aCols,cWorkSheet,cTable,lTotalize,lPicture)
/*/
Static Function GDToExcel(aHeader,aCols,cWorkSheet,cTable,lTotalize,lPicture)


Local oFWMSExcel := FWMSExcel():New()

Local oMsExcel

Local aCells

Local cType
Local cColumn

Local cFile
Local cFileTMP

Local cPicture

Local lTotal

Local nRow
Local nRows
Local nField
Local nFields

Local nAlign
Local nFormat

Local uCell

DEFAULT cWorkSheet := "GETDADOS"
DEFAULT cTable := cWorkSheet
DEFAULT lTotalize := .T.
DEFAULT lPicture := .F.

BEGIN SEQUENCE

oFWMSExcel:AddworkSheet(cWorkSheet)
oFWMSExcel:AddTable(cWorkSheet,cTable)

nFields := Len( aHeader )
For nField := 1 To nFields
cType := aHeader[nField][__AHEADER_TYPE__]
nAlign := IF(cType=="C",1,IF(cType=="N",3,2))
nFormat := IF(cType=="D",4,IF(cType=="N",2,1))
cColumn := aHeader[nField][__AHEADER_TITLE__]
lTotal := ( lTotalize .and. cType == "N" )
oFWMSExcel:AddColumn(@cWorkSheet,@cTable,@cColumn,@nAlign,@nFormat,@lTotal)
Next nField

aCells := Array(nFields)

nRows := Len( aCols )
For nRow := 1 To nRows
For nField := 1 To nFields
uCell := aCols[nRow][nField]
IF ( lPicture )
cPicture := aHeader[nField][__AHEADER_PICTURE__]
IF .NOT.( Empty(cPicture) )
uCell := Transform(uCell,cPicture)
EndIF
EndIF
aCells[nField] := uCell
Next nField
oFWMSExcel:AddRow(@cWorkSheet,@cTable,aClone(aCells))
Next nRow

oFWMSExcel:Activate()

cFile := ( CriaTrab( NIL, .F. ) + ".xml" )

While File( cFile )
cFile := ( CriaTrab( NIL, .F. ) + ".xml" )
End While

oFWMSExcel:GetXMLFile( cFile )
oFWMSExcel:DeActivate()

IF .NOT.( File( cFile ) )
cFile := ""
BREAK
EndIF

cFileTMP := ( GetTempPath() + cFile )
IF .NOT.( __CopyFile( cFile , cFileTMP ) )
fErase( cFile )
cFile := ""
BREAK
EndIF

fErase( cFile )

cFile := cFileTMP

IF .NOT.( File( cFile ) )
cFile := ""
BREAK
EndIF

IF .NOT.( ApOleClient("MsExcel") )
BREAK
EndIF

oMsExcel := MsExcel():New()
oMsExcel:WorkBooks:Open( cFile )
oMsExcel:SetVisible( .T. )
oMsExcel := oMsExcel:Destroy()

END SEQUENCE

oFWMSExcel := FreeObj( oFWMSExcel )

Return( cFile )



O código original poderá ser obtido ao clicar aqui.



[]s
иαldσ dj

Comentários

  1. Naldo, desculpe aproveitar esse post, mas por gentileza, vc poderia disponibilizar o arquivo de configuração do DevStudio com as cores da fonte do editor personalizadas (fundo preto etc)?
    Procurei no site e não encontrei.
    Já perdi um tempo tentando deixar o editor mais legível e "agradável", mas sempre escapa alguma coisa e não fica do jeito que eu gostaria. É bem mais complexo do que o antigo IDE...

    Obrigado!

    ResponderExcluir
  2. Naldo, nao encontrei aqui, mas voce ja fez algo para integrar com o outlook MS? se não, voce tem alguma idéia de como fazer?

    ResponderExcluir
    Respostas
    1. Caio, já tentou as classes TMailManager (http://tdn.totvs.com.br/display/tec/TMailManager) e TMailMessage (http://tdn.totvs.com.br/display/tec/TMailMessage)

      Excluir
  3. Muito boa a função, me deu uma grande ajuda. Parabéns pelo trabalho.

    ResponderExcluir

Postar um comentário

Postagens mais visitadas deste blog

BlackTDN :: RLeg ~ Desvendando a Função ParamBox

Para quem precisar desenvolver uma interface de entrada de dados, coisa rápida, e não quer ter aquele trabalhão danado que todos já sabemos, o Protheus tem uma função que ajuda muito, é uma interface semelhante a função Pergunte, porém com muito mais opção de objeto de entrada de dados, alias até colocar o scrollbox desta interface com todos os objetos em outra MsDialog ou Wizard é simples. Vejam o exemplo abaixo, boa sorte! Rleg. //---------------------------------------------------------- // Função exemplo utilizando a função ParamBox() //---------------------------------------------------------- User Function xParamBox() Local aRet := {} Local aParamBox := {} Local aCombo := {"Janeiro","Fevereiro","Março","Abril","Maio","Junho","Julho","Agosto","Setembro","Outubro","Novembro","Dezembro"} Local i := 0 Private cCadastro := "xParambox" // ---------------

BlackTDN :: Customizando a interface de Login no Protheus e by You

A publicação “ BlackTDN :: By You e sua nova tela de login ”  de nosso amigo OBona deu o que falar e, em função disso, esse que a muito não vos escreve resolveu criar uma versão onde será possível personalizar, “por completo”, a tela de login no Protheus/by You. Considerando que OBona já havia “mapeado, identificado e customizado” as imagens peguei-as emprestadas para o exemplo que se segue: O primeiro passo para a customização “total” da interface de login do Protheus/by You será implementar o “Ponto de Entrada” ChgPrDir (Diretório de impressão) . Usaremos esse PE juntamente como programa U_FindMsObject.prg (apresentado pela primeira vez em: Protheus :: ADVPL : The Container : Presents Pandora's box ). Diferente do exemplo proposto por OBona, que substitui, durante o processo de compilação, as imagens padrões do sistema (excluindo-as) por imagens customizadas (com o mesmo nome) este novo exemplo mantém, no RPO, as imagens padrões adicionando novas imagens customizadas que serã

Protheus :: Chamando Funções do Menu Diretamente e sem a Necessidade de Login

Ferne$ perguntou: "...é possível abrir alguma rotina do sistema sem solicitar login ao usuário, como por exemplo a rotina MATA010..." Sim Ferne$, é possível sim. Abaixo um Exemplo para a Chamada à função MATA010 sem a necessidade de Login no sistema. #INCLUDE "PROTHEUS.CH" #INCLUDE "TBICONN.CH" /*/ Funcao: MATA010Ex Data: 30/04/2011 Autor: Marinaldo de Jesus Descricao: Executar a Funcao MATA010 diretamente sem a necessidade de LOGIN no Protheus Sintaxe: 1 ) U_MATA010Ex ( Chamada diretamente na Tela de Entrada do Sistema ) ; ou 2 ) totvsclient.exe -q -p=u_MATA010Ex -a=01;01 -c=rnp_local -e=rnp -m -l ( Chamada Via Linha de Comando ) /*/ User Function MATA010Ex( cEmpFil ) Local aEmpFil Local bWindowInit := { || __Execute( "MATA010()" , "xxxxxxxxxxxxxxxxxxxx" , "MATA010" , "SIGAFAT" , "SIGAFAT", 1 , .T. ) } Local cEmp Local cFil Local cMod Local cModName := "SIGAFAT" DEFA