Protheus :: Advpl :: TCInternal()

Fala ae Anonimo!

Em um dos posts anteriores.. comenterei sobre o uso de algumas funções para nao ocorrer o consumo de licenças no TOP / DBAccess… e logo na sequencia houve um pedido “anonimo”

para postar o uso da TCInternal() na atualização de campos / dicionario de dados…

Postado ao som de : Delinquent Habits – Here Come The Horns

Como prometido… segue abaixo o codigo contendo o uso:

 

#include "protheus.ch"

/*
Funcao: UPDGema
Autor: Rodrigo OverFail
Data: 21/12/2011
Funcionalidade: Exemplo para uso da TCInternal()
*/

User Function UpdGema()

cArqEmp     := "SigaMat.Emp"
nModulo        := 05
__cInterNet := Nil
PRIVATE cMessage
PRIVATE aArqUpd     := {}
PRIVATE aREOPEN     := {}
Private __lPyme  := .F.

#IFDEF TOP
    TCInternal(5,'*OFF') //-- Desliga Refresh no Lock do Top
#ENDIF

Set Dele On

GEMOpenSM0(.T.)
DbGoTop()

lHistorico     := MsgYesNo("Atualização das tabelas e campos de exemplo UPDGema, Confirma?", "Update")
lEmpenho    := .F.
lAtuMnu        := .F.

DEFINE WINDOW oMainWnd FROM 0,0 TO 01,30 TITLE "Update"
ACTIVATE     WINDOW oMainWnd ICONIZED ;
            ON INIT (If(lHistorico ,Processa({||UpdTables()} ,"Atualização das tabelas") ,.F.), oMainWnd:End())

Return

Static Function GEMOpenSM0(lShared)
    Local lOpen := .F.                 
    Local i := 0
    For i := 1 To 20
        dbUseArea(.T., , "SIGAMAT.EMP", "SM0", lShared, .F.)
        If !Empty(Select("SM0"))
            lOpen := .T.
            dbSetIndex("SIGAMAT.IND")
            Exit   
        EndIf
        Sleep(500)
    Next
Return lOpen

Static Function UpdTables()
Local nRecno       := 0
Local nRecAtu     := 0
Local aAreaSM0     := {}

While SM0->(!Eof())
    nRecAtu := SM0->(Recno())
    aAreaSM0 := SM0->(GetArea())
    RpcSetType(3)
    RpcSetEnv(SM0->M0_CODIGO, SM0->M0_CODFIL)
    RestArea(aAreaSM0)
    SM0->(dbGoto(nRecAtu))
    RpcClearEnv()
    GEMOpenSM0(.F.)
    SM0->(dbGoto(nRecAtu))
    SM0->(dbSkip())

    If SM0->(! Eof())
        nRecno := SM0->(Recno())
        SM0->(DbGoTo(nRecno))
    EndIf   

EndDo

dbSelectArea("SM0")
dbGotop()
While SM0->(!Eof())

    nRecAtu := SM0->(Recno())
    aAreaSM0 := SM0->(GetArea())
    RpcSetType(3)
    RpcSetEnv(SM0->M0_CODIGO, SM0->M0_CODFIL)

    RestArea(aAreaSM0)

    dbSelectArea("SM0")
    dbGoto(nRecAtu)       
    If HasTemplate("LOT")
        dbGoto(nRecAtu)       
        dbSelectArea("SX3")
        dbSetOrder(2)
        If SX3->(dbSeek("LJN_TPPRIC"))
            RecLock("SX3",.F.)
            SX3->X3_WHEN := "t_VerWhenLJN()"
            MsUnlock()
        EndIf
    ENDIF     
    SM0->(dbGoto(nRecAtu))
    SM0->(dbSkip())

    If SM0->(! Eof())
        nRecno := SM0->(Recno())
        SM0->(DbGoTo(nRecno))
    EndIf   
EndDo

Alert("Fim da atualização")

Return(.T.)

User Function UpdGemSini()

cArqEmp     := "SigaMat.Emp"
nModulo        := 05
__cInterNet := Nil
PRIVATE cMessage
PRIVATE aArqUpd     := {}
PRIVATE aREOPEN     := {}
Private __lPyme  := .F.

#IFDEF TOP
    TCInternal(5,'*OFF') //-- Desliga Refresh no Lock do Top
#ENDIF

Set Dele On

GEMOpenSM0(.T.)
DbGoTop()

lHistorico     := MsgYesNo("Atualização dos campos do template de exmplo com base SINIEF, Confirma?", "Update")
lEmpenho    := .F.
lAtuMnu        := .F.

DEFINE WINDOW oMainWnd FROM 0,0 TO 01,30 TITLE "Update"
ACTIVATE     WINDOW oMainWnd ICONIZED ;
            ON INIT (If(lHistorico ,Processa({||AuxGEMSINIEF()} ,"Atualização das tabelas") ,.F.), oMainWnd:End())

Return
Static Function AuxGEMSINIEF()
Local nRecno   := 0
Local nCnt     :=0

Local nRecAtu := 0
Local aAreaSM0 := {}

While SM0->(!Eof())
    nRecAtu := SM0->(Recno())
    aAreaSM0 := SM0->(GetArea())
    RpcSetType(3)
    RpcSetEnv(SM0->M0_CODIGO, SM0->M0_CODFIL)
    RestArea(aAreaSM0)
    SM0->(dbGoto(nRecAtu))
    RpcClearEnv()
    GEMOpenSM0(.F.)
    SM0->(dbGoto(nRecAtu))
    SM0->(dbSkip())

    If SM0->(! Eof())
        nRecno := SM0->(Recno())
        SM0->(DbGoTo(nRecno))
    EndIf   

EndDo

dbSelectArea("SM0")
dbGotop()
While SM0->(!Eof())

    nRecAtu := SM0->(Recno())
    aAreaSM0 := SM0->(GetArea())
    RpcSetType(3)
    RpcSetEnv(SM0->M0_CODIGO, SM0->M0_CODFIL)

    RestArea(aAreaSM0)

    dbSelectArea("SM0")
    dbGoto(nRecAtu)       
    If HasTemplate("LOT")
        dbGoto(nRecAtu)       
        dbSelectArea("SXG")
        dbSetOrder(1)
        If dbSeek("018")        
            nSize := SXG->XG_SIZE
            aSX2Alias := {}
            aSX3Field := {}
            aAdd( aSX3Field ,{"LIT" ,"LIT_DOC" })
            aAdd( aSX3Field ,{"LIU" ,"LIU_DOC" })
            aAdd( aSX3Field ,{"LIT" ,"LIT_DUPL"})
            aAdd( aSX3Field ,{"LIW" ,"LIW_NUM" })
            aAdd( aSX3Field ,{"LIY" ,"LIY_NUM" })
            aAdd( aSX3Field ,{"LJA" ,"LJA_DOC" })
            aAdd( aSX3Field ,{"LJA" ,"LJA_DUPL"})
            aAdd( aSX3Field ,{"LJB" ,"LJB_DOC" })
            aAdd( aSX3Field ,{"LJE" ,"LJE_NUM" })
            aAdd( aSX3Field ,{"LJV" ,"LJV_NUM" })
            aAdd( aSX3Field ,{"LJX" ,"LJX_NUM" })
            aAdd( aSX3Field ,{"LJT" ,"LJT_NUM" })
            aAdd( aSX3Field ,{"LIX" ,"LIX_NUM" })
            aAdd( aSX3Field ,{"LK7" ,"LK7_NUM" })
            ProcRegua(Len(aSX3Field))
            For nCnt := 1 To Len(aSX3Field)
                IncProc("Atualizando o dicionario de campos...")

                dbSelectArea("SX3")
                dbSetOrder(2)
                If dbSeek(aSX3Field[nCnt ,02])
                    If SX3->X3_ARQUIVO == aSX3Field[nCnt ,01]
                        If aScan(aSX2Alias,{|x| x == SX3->X3_ARQUIVO })==0
                            aAdd(aSX2Alias ,SX3->X3_ARQUIVO)
                        EndIf
                        RecLock("SX3",.F.)
                            SX3->X3_TAMANHO := nSize
                            SX3->X3_GRPSXG  := "018"
                        MsUnLock()
                        dbCommit()
                    EndIf
                EndIf
            Next nCnt

               ProcRegua(Len(aSX2Alias))
            __SetX31Mode(.F.)
            For nCnt := 1 To Len(aSX2Alias)
                IncProc("Atualizando a estrutura da tabela: " +aSX2Alias[nCnt])
                If Select(aSX2Alias[nCnt])>0
                    dbSelecTArea(aSX2Alias[nCnt])
                    dbCloseArea()
                EndIf
                X31UpdTable(aSX2Alias[nCnt])
                If __GetX31Error()
                    Alert(__GetX31Trace())
                    Aviso("Erro!!!", "Falha na atualizacao da tabela: " + aSX2Alias[nCnt] + ". ", {"OK"},2)
                EndIf
            Next nX
            If Len(aSX2Alias) >0
                Alert("Atenção!!!" +chr(13)+chr(10) +;
                      "Foram atualizados " + AllTrim(str(Len(aSX2Alias))) + " tabelas referentes ao SINIEF.")
            EndIf
        Else
            Alert("Atenção!!!" +chr(13)+chr(10) +;
                  "O grupo de campo 018 - Documento de entrada/saida não existe. " +chr(13)+chr(10) +;
                  "Verifique se o atualizador do SINIEF foi executado anteriormente.")
        EndIf
    EndIf         
    dbSelectArea("SM0")
    dbGoto(nRecAtu)

    aAreaSM0 := SM0->(GetArea())
    RpcClearEnv()
    RestArea(aAreaSM0)
    GEMOpenSM0(.F.)

    dbSelectArea("SM0")
    dbGoto(nRecAtu)
    SM0->(dbSkip())
    If SM0->(! Eof())
        nRecno := SM0->(Recno())
        SM0->(DbGoTo(nRecno))
    EndIf
EndDo

Alert("Fim da atualização")

Return(.T.)

Rodrigo “OverFail”