BlackTDN :: Classe não documentada ~ MsSpool (abrir relatório posicionando na última página)

Cada dúvida que me aparece. Nem sempre tenho tempo para responder a todas, mas está me instigou.

A dúvida:

“Oi, você sabe se é possível, ou tem algum exemplo de como abrir um relatório no modelo antigo (que usa essas funções (http://tdn.totvs.com/pages/releaseview.action?pageId=6815072) posicionado  na ultima pagina? ... o que eu estou tentando fazer é o seguinte. Digamos que o relatório tenha cinco páginas, que quero que quando ele carregue, ele venha direto na pagina cinco.

Eu já procurei bastante, mas acho que não da pra fazer isso...

Desde já Obrigado pela atenção. (Leonardo Gregório de Almeida)”

A solução:

Pensei que seria impossível uma vez que os relatórios são abertos com a OurSpool (Gerenciador de impressão) mas OurSpool não faz nada a não ser  instanciar a Classe não documentada MsSpool.

MsSpool é, de fato, o gerenciador de impressão do Protheus.

Depois de algumas tentativas e erros com MsSpool cheguei ao seguinte:

#INCLUDE "PROTHEUS.CH"

#INCLUDE "MSOBJECT.CH"

User Function TMsSpool()

    Local cFileR3    := "GPER040" //Para o teste informe um relatório com + de 1 Pagina e existente no seu Spool

    OurSpoolLP(cFileR3)

Return( NIL )

Static Function OurSpoolLP(cFileR3)

    Local oBTDNSPool := BTDNSPool():New()

    IF .NOT.( Empty(cFileR3) )

        oBTDNSPool:lShowDir    := .F.

        oBTDNSPool:cRelName    := cFileR3 + ".##R"

        //Define o Diretório de Impressao

        oBTDNSPool:cRelDir    := AllTrim(LastRELDIR())

        IF ( Empty(oBTDNSPool:cRelDir) )

            //Redefine o Diretório de Impressao considerando __RELDIR

            oBTDNSPool:cRelDir := AllTrim(__RELDIR)

            IF ( Empty(oBTDNSPool:cRelDir) ) .and. ( Select("SX6") > 0 )

                //Redefine o Diretório de Impressao considerando MV_RELDIR

                oBTDNSPool:cRelDir := AllTrim(GetMv("MV_RELDIR"))

            EndIF            

        EndIF

        //Garante que eh um diretório

        IF .NOT.( SubStr(oBTDNSPool:cRelDir,-1) == "\")

            oBTDNSPool:cRelDir += "\"

        EndIF

        //Verifica origem

        IF ( ":\" $ oBTDNSPool:cRelDir )

            //Cliente

            oBTDNSPool:nFilesFrom := 2 

        Else

            //Servidor

            oBTDNSPool:nFilesFrom := 1

        EndIF

        //Antes de chamar o método Show() você faz o posicionamento

        //Carrega o relatório em memoria para obter o numero de paginas

        oBTDNSPool:LoadRel()

        //Define a pagina Atual como sendo a Ultima

        oBTDNSPool:nRelPage      := oBTDNSPool:nRelPages    

        oBTDNSPool:nPRTPageStart := oBTDNSPool:nRelPage

        //Carrega a Pagina

        oBTDNSPool:LoadPage(oBTDNSPool:nRelPage)            

        //Mostra a Tela de Spool

        oBTDNSPool:Show()

        //Encerra

        oBTDNSPool:CloseReport()    

    EndIF

Return( NIL )

//Encapsulo a Classe MsSpool

CLASS BTDNSPool FROM MSSPOOL

    DATA cLastRelName

    METHOD NEW() CONSTRUCTOR

    METHOD LoadRel()

ENDCLASS

//Redefino NEW()

Method New() CLASS BTDNSPool

Return(_Super:New())

//Redefino LoadRel()

Method LoadRel() CLASS BTDNSPool

    //"AQUI ESTA O PULO DO GATO" : Só Recarrega se não estiver carregado

    IF .NOT.( Self:cLastRelName == Self:cRelName )

        Self:cLastRelName := Self:cRelName

        _Super:LoadRel()

    EndIF

Return(NIL)

Bom Proveito (Obs.: Testado nas versões 10 e 11 do Protheus).

[]s
иαldσ dj